[gentoo-commits] gentoo-x86 commit in net-analyzer/cacti-spine: cacti-spine-0.8.8b.ebuild ChangeLog

[Jorge Manuel B. S. Vicetto (jmbsvicetto)]

jmbsvicetto    13/08/27 02:19:17

  Modified:             ChangeLog
  Added:                cacti-spine-0.8.8b.ebuild
  Log:
  Copy cacti-spine from my overlay.
  Bump cacti-spine to the 0.8.8b release
  
  (Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key BB0E6E98)

Revision  Changes    Path
1.38                 net-analyzer/cacti-spine/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti-spine/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti-spine/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti-spine/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/cacti-spine/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	27 Apr 2013 15:09:23 -0000	1.37
+++ ChangeLog	27 Aug 2013 02:19:17 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/cacti-spine
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti-spine/ChangeLog,v 1.37 2013/04/27 15:09:23 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti-spine/ChangeLog,v 1.38 2013/08/27 02:19:17 jmbsvicetto Exp $
+
+*cacti-spine-0.8.8b (27 Aug 2013)
+
+  27 Aug 2013; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
+  +cacti-spine-0.8.8b.ebuild, +files/cacti-spine-0.8.8b-fix-ac-macro.patch:
+  Copy cacti-spine from my overlay. Bump cacti-spine to the 0.8.8b release
 
 *cacti-spine-0.8.8a (27 Apr 2013)
 



1.1                  net-analyzer/cacti-spine/cacti-spine-0.8.8b.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti-spine/cacti-spine-0.8.8b.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/cacti-spine/cacti-spine-0.8.8b.ebuild?rev=1.1&content-type=text/plain

Index: cacti-spine-0.8.8b.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/cacti-spine/cacti-spine-0.8.8b.ebuild,v 1.1 2013/08/27 02:19:17 jmbsvicetto Exp $

EAPI="4"
inherit autotools eutils

UPSTREAM_PATCHES=""

MY_P=${PN}-${PV/_p/-}

DESCRIPTION="Spine is a fast poller for Cacti (formerly known as Cactid)"
HOMEPAGE="http://cacti.net/spine_info.php"
SRC_URI="http://www.cacti.net/downloads/spine/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""

DEPEND="net-analyzer/net-snmp
	dev-libs/openssl
	virtual/mysql"
RDEPEND="${DEPEND}
	>net-analyzer/cacti-0.8.8"

if [[ -n ${UPSTREAM_PATCHES} ]]; then
	for i in ${UPSTREAM_PATCHES}; do
		SRC_URI="${SRC_URI} http://www.cacti.net/downloads/spine/patches/${PV}/${i}.patch"
	done
fi

src_prepare() {
	# Patch configure.ac to replace AM_CONFIG_HEADER with AC_CONFIG_HEADERS
	epatch "${FILESDIR}/${P}-fix-ac-macro.patch"

	if [[ -n ${UPSTREAM_PATCHES} ]]; then
		for i in ${UPSTREAM_PATCHES} ; do
			EPATCH_OPTS="-p1 -N" epatch "${DISTDIR}"/${i}.patch
		done
	fi

	sed -i -e 's/^bin_PROGRAMS/sbin_PROGRAMS/' Makefile.am
	AT_M4DIR="config" eautoreconf
}

src_install() {
	dosbin spine || die
	insinto /etc/
	insopts -m0640 -o root
	newins spine.conf{.dist,} || die
	dodoc ChangeLog README || die
}

pkg_postinst() {
	elog "Please see the cacti's site for installation instructions:"
	elog
	elog "http://cacti.net/spine_install.php"
	echo
	ewarn "/etc/spine.conf should be readable by webserver, thus after you"
	ewarn "decide on webserver do not forget to run the following command:"
	ewarn
	ewarn " # chown root:<wwwgroup> /etc/spine.conf"
	echo
}