[gentoo-commits] gentoo-x86 commit in sci-calculators/units: units-2.10.ebuild ChangeLog metadata.xml

[Jeroen Roovers (jer)]

jer         14/03/27 20:01:15

  Modified:             ChangeLog metadata.xml
  Added:                units-2.10.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.68                 sci-calculators/units/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-calculators/units/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	4 Feb 2014 08:37:25 -0000	1.67
+++ ChangeLog	27 Mar 2014 20:01:15 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for sci-calculators/units
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-calculators/units/ChangeLog,v 1.67 2014/02/04 08:37:25 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-calculators/units/ChangeLog,v 1.68 2014/03/27 20:01:15 jer Exp $
+
+*units-2.10 (27 Mar 2014)
+
+  27 Mar 2014; Jeroen Roovers <jer@g.o> +units-2.10.ebuild,
+  +files/units-2.10-install.patch, metadata.xml:
+  Version bump.
 
 *units-2.02-r1 (04 Feb 2014)
 



1.5                  sci-calculators/units/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-calculators/units/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	14 Jan 2013 20:24:25 -0000	1.4
+++ metadata.xml	27 Mar 2014 20:01:15 -0000	1.5
@@ -5,4 +5,7 @@
 <email>jer@g.o</email>
 <name>Jeroen Roovers</name>
 </maintainer>
+<use>
+<flag name='units_cur'>Install the units_cur python script that updates currencies</flag>
+</use>
 </pkgmetadata>



1.1                  sci-calculators/units/units-2.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/units-2.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-calculators/units/units-2.10.ebuild?rev=1.1&content-type=text/plain

Index: units-2.10.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-calculators/units/units-2.10.ebuild,v 1.1 2014/03/27 20:01:15 jer Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
PYTHON_REQ_USE="xml"
inherit autotools eutils python-r1

DESCRIPTION="Unit conversion program"
HOMEPAGE="http://www.gnu.org/software/units/units.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="FDL-1.3 GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86 ~amd64-linux ~x86-linux"
IUSE="+units_cur"

DEPEND="
	>=sys-libs/readline-4.1-r2
	units_cur? (
		dev-lang/python-exec:2
		dev-python/unidecode[${PYTHON_USEDEP}]
	)
"
RDEPEND="
	${DEPEND}
"

DOCS=( ChangeLog NEWS README )

units_cur_prepare() {
	local UNITS_PYTHON_MAJOR
	UNITS_PYTHON_MAJOR=$(
		UNITS_PYTHON_MAJOR=${EPYTHON/.*}
		shopt -s extglob
		echo ${UNITS_PYTHON_MAJOR/*([[:alpha:]])}
	)
	sed -e "/^outfile/s|'.*'|'/usr/share/units/currency.units'|g" units_cur${UNITS_PYTHON_MAJOR} > units_cur-${EPYTHON}
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-install.patch
	eautoreconf
	use units_cur && python_foreach_impl units_cur_prepare
}

src_compile() {
	emake HAVE_PYTHON=no
}

units_cur_install() {
	python_newexe units_cur-${EPYTHON} units_cur
}

src_install() {
	emake DESTDIR="${D}" HAVE_PYTHON=no install

	use units_cur && python_foreach_impl units_cur_install
}