[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgusb/

[Mike Gilbert]

commit:     55e66fa3b5eee0fc1324583ae41f2b2db75b9b65
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 00:58:24 2021 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sun Nov 28 19:54:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55e66fa3

dev-libs/libgusb: migrate to hwdata

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 dev-libs/libgusb/libgusb-0.3.7-r1.ebuild | 63 ++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

diff --git a/dev-libs/libgusb/libgusb-0.3.7-r1.ebuild b/dev-libs/libgusb/libgusb-0.3.7-r1.ebuild
new file mode 100644
index 000000000000..304bd87d1a25
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.3.7-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection static-libs test +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	sys-apps/hwdata
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.4
+		dev-util/gtk-doc
+	)
+	vala? ( $(vala_depend) )
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	default
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+		$(meson_use test tests)
+		$(meson_native_use_bool vala vapi)
+		-Dusb_ids="${EPREFIX}"/usr/share/hwdata/usb.ids
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_bool introspection)
+
+	)
+	meson_src_configure
+}