[gentoo-commits] gentoo-x86 commit in sci-electronics/klayout: ChangeLog klayout-0.21.11.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    11/07/25 22:05:22

  Modified:             ChangeLog
  Added:                klayout-0.21.11.ebuild
  Log:
  Version bump, add missing ruby dependency (bug 369055)
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  sci-electronics/klayout/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/klayout/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/klayout/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/klayout/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/klayout/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	29 May 2011 08:46:30 -0000	1.7
+++ ChangeLog	25 Jul 2011 22:05:21 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for sci-electronics/klayout
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/klayout/ChangeLog,v 1.7 2011/05/29 08:46:30 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/klayout/ChangeLog,v 1.8 2011/07/25 22:05:21 dilfridge Exp $
+
+*klayout-0.21.11 (25 Jul 2011)
+
+  25 Jul 2011; Andreas K. Huettel <dilfridge@g.o>
+  +klayout-0.21.11.ebuild:
+  Version bump, add missing ruby dependency (bug 369055)
 
   29 May 2011; Andreas K. Huettel <dilfridge@g.o>
   -klayout-0.21.7.ebuild:



1.1                  sci-electronics/klayout/klayout-0.21.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/klayout/klayout-0.21.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/klayout/klayout-0.21.11.ebuild?rev=1.1&content-type=text/plain

Index: klayout-0.21.11.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/klayout/klayout-0.21.11.ebuild,v 1.1 2011/07/25 22:05:21 dilfridge Exp $

EAPI=3

USE_RUBY="ruby18"
# note: define maximally ONE implementation here

RUBY_OPTIONAL=yes

inherit eutils multilib toolchain-funcs ruby-ng

DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
HOMEPAGE="http://www.klayout.de/"
SRC_URI="http://www.klayout.de/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ruby"

RDEPEND="
	x11-libs/qt-gui:4[qt3support]
	ruby? ( $(ruby_implementations_depend) )
"
DEPEND="${RDEPEND}"

all_ruby_prepare() {
	# now we generate the stub build configuration file for the home-brew build system
	cp "${FILESDIR}/${PN}-0.21.7-Makefile.conf.linux-gentoo" "${S}/config/Makefile.conf.linux-gentoo" || die
}

each_ruby_configure() {
	local rbflags

	if use ruby ; then
		rbflags="-rblib $(ruby_get_libruby) -rbinc $(ruby_get_hdrdir)"
	fi

	./build.sh \
		-dry-run \
		-platform linux-gentoo \
		-bin bin \
		-qtbin /usr/bin \
		-qtinc /usr/include/qt4 \
		-qtlib /usr/$(get_libdir)/qt4 \
		${rbflags} || die "Configuration failed"
}

each_ruby_compile() {
	cd build.linux-gentoo
	tc-export CC CXX AR LD RANLIB
	export AR="${AR} -r"
	emake all || die "Build failed"
}

each_ruby_install() {
	cd build.linux-gentoo
	emake install || die "make install failed"

	cd ..
	dobin bin/klayout || die

	insinto /usr/share/${PN}/testdata/gds
	doins testdata/gds/*.gds || die "Installation of gds testdata failed"
	insinto /usr/share/${PN}/testdata/oasis
	doins testdata/oasis/*.oas testdata/oasis/*.ot || die "Installation of oasis testdata failed"

	if use ruby; then
		insinto /usr/share/${PN}
		doins -r testdata/ruby || die "Installation of ruby testdata failed"
	fi
}