[gentoo-commits] gentoo-x86 commit in net-misc/memcached: ChangeLog memcached-1.4.5.ebuild

[Robin H. Johnson (robbat2)]

robbat2     10/04/04 21:27:49

  Modified:             ChangeLog
  Added:                memcached-1.4.5.ebuild
  Log:
  Version bump for bugfix edition.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.108                net-misc/memcached/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/memcached/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/memcached/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/memcached/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/memcached/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -p -w -b -B -u -u -r1.107 -r1.108
--- ChangeLog	7 Jan 2010 15:55:42 -0000	1.107
+++ ChangeLog	4 Apr 2010 21:27:49 -0000	1.108
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/memcached
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/memcached/ChangeLog,v 1.107 2010/01/07 15:55:42 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/memcached/ChangeLog,v 1.108 2010/04/04 21:27:49 robbat2 Exp $
+
+*memcached-1.4.5 (04 Apr 2010)
+
+  04 Apr 2010; Robin H. Johnson <robbat2@g.o>
+  +memcached-1.4.5.ebuild:
+  Version bump for bugfix edition.
 
   07 Jan 2010; Christian Faulhammer <fauli@g.o>
   memcached-1.4.4.ebuild:



1.1                  net-misc/memcached/memcached-1.4.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/memcached/memcached-1.4.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/memcached/memcached-1.4.5.ebuild?rev=1.1&content-type=text/plain

Index: memcached-1.4.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/memcached/memcached-1.4.5.ebuild,v 1.1 2010/04/04 21:27:49 robbat2 Exp $

EAPI=2
inherit eutils autotools flag-o-matic

MY_PV="${PV/_rc/-rc}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="High-performance, distributed memory object caching system"
HOMEPAGE="http://code.google.com/p/memcached/"
SRC_URI="http://memcached.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="test slabs-reassign debug sasl" # hugetlbfs later

RDEPEND=">=dev-libs/libevent-1.4
		 dev-lang/perl
		 sasl? ( dev-libs/cyrus-sasl )"
DEPEND="${RDEPEND}
		test? ( virtual/perl-Test-Harness >=dev-perl/Cache-Memcached-1.24 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.2.2-fbsd.patch"
	# Handled different upstream
	#epatch "${FILESDIR}/${PN}-1.3.3-gcc4-slab-fixup.patch"
	epatch "${FILESDIR}/${PN}-1.4.0-fix-as-needed-linking.patch"
	epatch "${FILESDIR}/${PN}-1.4.4-as-needed.patch"
	sed -i -e 's,-Werror,,g' configure.ac || die "sed failed"
	eautoreconf
	use slabs-reassign && append-flags -DALLOW_SLABS_REASSIGN
}

src_configure() {
	econf \
		--disable-docs \
		$(use_enable sasl)
	# The xml2rfc tool to build the additional docs requires TCL :-(
	# `use_enable doc docs`
}

src_compile() {
	# There is a heavy degree of per-object compile flags
	# Users do NOT know better than upstream. Trying to compile the testapp and
	# the -debug version with -DNDEBUG _WILL_ fail.
	append-flags -UNDEBUG
	emake testapp memcached-debug CFLAGS="${CFLAGS}" || die "emake of testapp and memcached-debug failed."
	filter-flags -UNDEBUG
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dobin scripts/memcached-tool
	use debug && dobin memcached-debug

	dodoc AUTHORS ChangeLog NEWS README doc/{CONTRIBUTORS,*.txt}

	newconfd "${FILESDIR}"/1.3.3/conf memcached
	newinitd "${FILESDIR}"/1.3.3/init memcached
}

pkg_postinst() {
	enewuser memcached -1 -1 /dev/null daemon

	elog "With this version of Memcached Gentoo now supports multiple instances."
	elog "To enable this you should create a symlink in /etc/init.d/ for each instance"
	elog "to /etc/init.d/memcached and create the matching conf files in /etc/conf.d/"
	elog "Please see Gentoo bug #122246 for more info"
}

src_test() {
	emake -j1 test || die "Failed testing"
}