[gentoo-commits] gentoo-x86 commit in app-admin/salt: ChangeLog salt-2014.1.0.ebuild metadata.xml salt-9999.ebuild salt-0.17.4-r1.ebuild salt-0.16.4.ebuild salt-0.17.2.ebuild salt-0.17.4.ebuild

[Patrick McLean (chutzpah)]

chutzpah    14/02/27 00:02:32

  Modified:             ChangeLog metadata.xml salt-9999.ebuild
  Added:                salt-2014.1.0.ebuild
  Removed:              salt-0.17.4-r1.ebuild salt-0.16.4.ebuild
                        salt-0.17.2.ebuild salt-0.17.4.ebuild
  Log:
  Version bump. Update 9999 to match current release. Add "use logger" to init script (bug #502550). Clean out old versions.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.32                 app-admin/salt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	22 Jan 2014 20:40:48 -0000	1.31
+++ ChangeLog	27 Feb 2014 00:02:32 -0000	1.32
@@ -1,6 +1,16 @@
 # ChangeLog for app-admin/salt
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.31 2014/01/22 20:40:48 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.32 2014/02/27 00:02:32 chutzpah Exp $
+
+*salt-2014.1.0 (26 Feb 2014)
+
+  26 Feb 2014; Patrick McLean <chutzpah@g.o> -salt-0.16.4.ebuild,
+  -salt-0.17.2.ebuild, -salt-0.17.4.ebuild, -salt-0.17.4-r1.ebuild,
+  +salt-2014.1.0.ebuild, salt-9999.ebuild, -files/master-initd-1,
+  -files/minion-initd-1, -files/syndic-initd-1, +files/master-initd-3,
+  +files/minion-initd-3, +files/syndic-initd-3, metadata.xml:
+  Version bump. Update 9999 to match current release. Add "use logger" to init
+  script (bug #502550). Clean out old versions.
 
 *salt-0.17.4-r2 (22 Jan 2014)
 



1.5                  app-admin/salt/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/salt/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	4 May 2013 20:40:58 -0000	1.4
+++ metadata.xml	27 Feb 2014 00:02:32 -0000	1.5
@@ -26,6 +26,7 @@
 		<flag name="mongodb">Support returning data to a mongodb server.</flag>
 		<flag name="redis">Support returning data to a redis database.</flag>
 		<flag name="mako">Add support for using the mako template engine for parsing salt states.</flag>
+		<flag name="timelib">Use timelib to parse english textual date descriptions.</flag>
 	</use>
 </pkgmetadata>
 



1.9                  app-admin/salt/salt-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-9999.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-9999.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-9999.ebuild?r1=1.8&r2=1.9

Index: salt-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/salt/salt-9999.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- salt-9999.ebuild	3 Dec 2013 18:43:12 -0000	1.8
+++ salt-9999.ebuild	27 Feb 2014 00:02:32 -0000	1.9
@@ -1,12 +1,12 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-9999.ebuild,v 1.8 2013/12/03 18:43:12 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-9999.ebuild,v 1.9 2014/02/27 00:02:32 chutzpah Exp $
 
 EAPI=5
 
 PYTHON_COMPAT=(python{2_6,2_7})
 
-inherit eutils distutils-r1
+inherit eutils distutils-r1 systemd
 
 DESCRIPTION="Salt is a remote execution and configuration manager."
 HOMEPAGE="http://saltstack.org/"
@@ -24,9 +24,9 @@
 
 LICENSE="Apache-2.0"
 SLOT="0"
-IUSE="ldap libvirt mako mongodb mysql openssl redis test"
+IUSE="ldap libvirt mako mongodb mysql openssl redis timelib test"
 
-RDEPEND=">=dev-python/pyzmq-2.1.9[${PYTHON_USEDEP}]
+RDEPEND=">=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
 		dev-python/msgpack[${PYTHON_USEDEP}]
 		dev-python/pyyaml[${PYTHON_USEDEP}]
 		dev-python/m2crypto[${PYTHON_USEDEP}]
@@ -34,6 +34,7 @@
 		dev-python/pycryptopp[${PYTHON_USEDEP}]
 		dev-python/jinja[${PYTHON_USEDEP}]
 		dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}]
 		sys-apps/pciutils
 		mako? ( dev-python/mako[${PYTHON_USEDEP}] )
 		ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
@@ -45,32 +46,37 @@
 		)
 		mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
 		mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
-		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )"
+		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
+		timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )"
 DEPEND="test? (
+			dev-python/pip
 			dev-python/virtualenv
+			dev-python/SaltTesting
 			${RDEPEND}
 		)"
 
+PATCHES=("${FILESDIR}/${PN}-0.17.1-tests-nonroot.patch")
+DOCS=(README.rst AUTHORS)
+
 python_prepare() {
 	sed -i '/install_requires=/ d' setup.py || die "sed failed"
 }
 
 python_install_all() {
-	distutils-r1_python_install_all
+	USE_SETUPTOOLS=1 distutils-r1_python_install_all
 
 	for s in minion master syndic; do
-		newinitd "${FILESDIR}"/${s}-initd-1 salt-${s}
+		newinitd "${FILESDIR}"/${s}-initd-3 salt-${s}
 		newconfd "${FILESDIR}"/${s}-confd-1 salt-${s}
+		systemd_dounit "${FILESDIR}"/salt-${s}.service
 	done
 
 	insinto /etc/${PN}
 	doins conf/*
-
-	dodoc README.rst AUTHORS
 }
 
 python_test() {
 	# testsuite likes lots of files
 	ulimit -n 3072
-	SHELL="/bin/bash" TMPDIR=/tmp ./tests/runtests.py --unit-tests --no-report || die
+	USE_SETUPTOOLS=1 SHELL="/bin/bash" TMPDIR=/tmp ./tests/runtests.py --unit-tests --no-report --verbose || die
 }



1.1                  app-admin/salt/salt-2014.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-2014.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/salt/salt-2014.1.0.ebuild?rev=1.1&content-type=text/plain

Index: salt-2014.1.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-2014.1.0.ebuild,v 1.1 2014/02/27 00:02:32 chutzpah Exp $

EAPI=5

PYTHON_COMPAT=(python{2_6,2_7})

inherit eutils distutils-r1 systemd

DESCRIPTION="Salt is a remote execution and configuration manager."
HOMEPAGE="http://saltstack.org/"

if [[ ${PV} == 9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
	EGIT_BRANCH="develop"
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
	KEYWORDS="~x86 ~amd64"
fi

LICENSE="Apache-2.0"
SLOT="0"
IUSE="ldap libvirt mako mongodb mysql openssl redis timelib test"

RDEPEND=">=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
		dev-python/msgpack[${PYTHON_USEDEP}]
		dev-python/pyyaml[${PYTHON_USEDEP}]
		dev-python/m2crypto[${PYTHON_USEDEP}]
		dev-python/pycrypto[${PYTHON_USEDEP}]
		dev-python/pycryptopp[${PYTHON_USEDEP}]
		dev-python/jinja[${PYTHON_USEDEP}]
		dev-python/setuptools[${PYTHON_USEDEP}]
		>=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}]
		sys-apps/pciutils
		mako? ( dev-python/mako[${PYTHON_USEDEP}] )
		ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
		openssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
		libvirt? ( || (
			dev-python/libvirt-python[${PYTHON_USEDEP}]
			app-emulation/libvirt[python,${PYTHON_USEDEP}]
			)
		)
		mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
		mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
		timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )"
DEPEND="test? (
			dev-python/pip
			dev-python/virtualenv
			dev-python/SaltTesting
			${RDEPEND}
		)"

PATCHES=("${FILESDIR}/${PN}-0.17.1-tests-nonroot.patch")
DOCS=(README.rst AUTHORS)

python_prepare() {
	sed -i '/install_requires=/ d' setup.py || die "sed failed"

	# this test fails because it trys to "pip install distribute"
	rm tests/unit/{modules,states}/zcbuildout_test.py
}

python_install_all() {
	USE_SETUPTOOLS=1 distutils-r1_python_install_all

	for s in minion master syndic; do
		newinitd "${FILESDIR}"/${s}-initd-3 salt-${s}
		newconfd "${FILESDIR}"/${s}-confd-1 salt-${s}
		systemd_dounit "${FILESDIR}"/salt-${s}.service
	done

	insinto /etc/${PN}
	doins conf/*
}

python_test() {
	# testsuite likes lots of files
	ulimit -n 3072
	USE_SETUPTOOLS=1 SHELL="/bin/bash" TMPDIR=/tmp ./tests/runtests.py --unit-tests --no-report --verbose || die
}