[gentoo-commits] gentoo-x86 commit in media-video/subtitleeditor: subtitleeditor-0.41.0.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/10/03 20:19:12

  Modified:             ChangeLog
  Added:                subtitleeditor-0.41.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.22                 media-video/subtitleeditor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/subtitleeditor/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/subtitleeditor/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/subtitleeditor/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	29 Mar 2013 23:22:52 -0000	1.21
+++ ChangeLog	3 Oct 2013 20:19:12 -0000	1.22
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/subtitleeditor
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/ChangeLog,v 1.21 2013/03/29 23:22:52 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/ChangeLog,v 1.22 2013/10/03 20:19:12 pacho Exp $
+
+*subtitleeditor-0.41.0 (03 Oct 2013)
+
+  03 Oct 2013; Pacho Ramos <pacho@g.o> +subtitleeditor-0.41.0.ebuild:
+  Version bump
 
   29 Mar 2013; Gilles Dartiguelongue <eva@g.o>
   -subtitleeditor-0.37.1.ebuild:



1.1                  media-video/subtitleeditor/subtitleeditor-0.41.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/subtitleeditor/subtitleeditor-0.41.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/subtitleeditor/subtitleeditor-0.41.0.ebuild?rev=1.1&content-type=text/plain

Index: subtitleeditor-0.41.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/subtitleeditor-0.41.0.ebuild,v 1.1 2013/10/03 20:19:12 pacho Exp $

EAPI=5
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit gnome2 versionator flag-o-matic

DESCRIPTION="GTK+2 subtitle editing tool"
HOMEPAGE="http://home.gna.org/subtitleeditor/"
SRC_URI="http://download.gna.org/${PN}/$(get_version_component_range 1-2)/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug nls opengl"

RDEPEND="
	app-text/iso-codes
	>=dev-cpp/gtkmm-2.14:2.4
	>=dev-cpp/glibmm-2.16.3:2
	>=dev-cpp/libxmlpp-2.20:2.6
	>=app-text/enchant-1.4
	>=dev-cpp/gstreamermm-0.10.6
	>=media-libs/gst-plugins-good-0.10:0.10
	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
	>=media-plugins/gst-plugins-pango-0.10:0.10
	>=media-plugins/gst-plugins-xvideo-0.10:0.10
	opengl? ( >=dev-cpp/gtkglextmm-1.2 )
"
# gst-plugins-pango needed for text overlay
# gst-plugins-xvideo needed for video output
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40
	virtual/pkgconfig
"

src_configure() {
	export GST_REGISTRY="${T}/home/registry.cache.xml"

	# Avoid using --enable-debug as it mocks with CXXFLAGS and LDFLAGS
	use debug && append-flags -DDEBUG

	gnome2_src_configure \
		--disable-debug \
		$(use_enable nls) \
		$(use_enable opengl gl)
}