[gentoo-commits] gentoo-x86 commit in media-libs/openexr: ChangeLog openexr-1.6.1.ebuild

[Alexis Ballier (aballier)]

aballier    07/10/27 18:20:20

  Modified:             ChangeLog
  Added:                openexr-1.6.1.ebuild
  Log:
  version bump, bug #197219
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.63                 media-libs/openexr/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/openexr/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/openexr/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/openexr/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/openexr/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	24 Oct 2007 12:01:24 -0000	1.62
+++ ChangeLog	27 Oct 2007 18:20:20 -0000	1.63
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/openexr
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/openexr/ChangeLog,v 1.62 2007/10/24 12:01:24 uberlord Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/openexr/ChangeLog,v 1.63 2007/10/27 18:20:20 aballier Exp $
+
+*openexr-1.6.1 (27 Oct 2007)
+
+  27 Oct 2007; Alexis Ballier <aballier@g.o> +openexr-1.6.1.ebuild:
+  version bump, bug #197219
 
   24 Oct 2007; Roy Marples <uberlord@g.o> openexr-1.6.0.ebuild:
   Keyworded ~x86-fbsd, #142921



1.1                  media-libs/openexr/openexr-1.6.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/openexr/openexr-1.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/openexr/openexr-1.6.1.ebuild?rev=1.1&content-type=text/plain

Index: openexr-1.6.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/openexr/openexr-1.6.1.ebuild,v 1.1 2007/10/27 18:20:20 aballier Exp $

inherit libtool

DESCRIPTION="ILM's OpenEXR high dynamic-range image file format libraries"
HOMEPAGE="http://openexr.com/"
SRC_URI="http://download.savannah.nongnu.org/releases/openexr/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc examples"

RDEPEND="media-libs/ilmbase"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Replace the temporary directory used for tests.
	sed -i -e 's:"/var/tmp/":"'${T}'":' "IlmImfTest/tmpDir.h"

	# Sane versioning on FreeBSD - please don't remove elibtoolize
	elibtoolize
}

src_compile() {
	econf $(use_enable examples imfexamples)
	emake || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" examplesdir="/usr/share/doc/${PF}/examples" install || \
		die "install failed"
	dodoc AUTHORS ChangeLog NEWS README

	if use doc ; then
		insinto "/usr/share/doc/${PF}"
		doins doc/*.pdf
	fi
	rm -frv "${D}usr/share/doc/OpenEXR"*

	if use examples ; then
		dobin "IlmImfExamples/imfexamples"
	else
		rm -fr "${D}usr/share/doc/${PF}/examples"
	fi
}

pkg_postinst() {
	einfo "OpenEXR was divided into IlmBase, OpenEXR, and OpenEXR_Viewers."
	einfo "Viewers are available in OpenEXR_Viewers package."
	einfo "If you want them, run:"
	einfo
	einfo "emerge media-gfx/openexr_viewers"
	einfo

	ewarn "OpenEXR may have had ABI changes."
	ewarn "Please run revdep-rebuild"
	ewarn "to rebuild programs using it"
	ewarn "(like KDELibs, KRita, ImageMagick, etc.)."
}



-- 
gentoo-commits@g.o mailing list