[gentoo-commits] gentoo-x86 commit in sci-mathematics/gretl: ChangeLog gretl-1.9.0-r1.ebuild gretl-1.9.0.ebuild gretl-1.8.6.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    10/08/22 08:34:34

  Modified:             ChangeLog
  Added:                gretl-1.9.0-r1.ebuild
  Removed:              gretl-1.9.0.ebuild gretl-1.8.6.ebuild
  Log:
  Respect LDFLAGS wrt bug 333873. Thanks to Diego for report. Remove old.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 sci-mathematics/gretl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/gretl/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/gretl/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/gretl/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/gretl/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	11 May 2010 01:34:15 -0000	1.24
+++ ChangeLog	22 Aug 2010 08:34:34 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for sci-mathematics/gretl
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/gretl/ChangeLog,v 1.24 2010/05/11 01:34:15 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/gretl/ChangeLog,v 1.25 2010/08/22 08:34:34 xarthisius Exp $
+
+*gretl-1.9.0-r1 (22 Aug 2010)
+
+  22 Aug 2010; Kacper Kowalik <xarthisius@g.o> -gretl-1.8.6.ebuild,
+  -gretl-1.9.0.ebuild, +gretl-1.9.0-r1.ebuild,
+  +files/gretl-1.9.0-ldflags.patch:
+  Respect LDFLAGS wrt bug 333873. Thanks to Diego for report. Remove old.
 
   11 May 2010; Sébastien Fabbro <bicatali@g.o> gretl-1.9.0.ebuild:
   Removed TODO from dodoc



1.1                  sci-mathematics/gretl/gretl-1.9.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/gretl/gretl-1.9.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/gretl/gretl-1.9.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: gretl-1.9.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/gretl/gretl-1.9.0-r1.ebuild,v 1.1 2010/08/22 08:34:34 xarthisius Exp $

USE_EINSTALL=true
EAPI=2
inherit eutils gnome2 elisp-common

DESCRIPTION="Regression, econometrics and time-series library"
HOMEPAGE="http://gretl.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="accessibility emacs gmp gnome gtk nls odbc openmp readline R sourceview"

RDEPEND="dev-libs/libxml2
	dev-libs/glib:2
	>=sci-visualization/gnuplot-4.2
	virtual/lapack
	virtual/latex-base
	sci-libs/fftw:3.0
	dev-libs/mpfr
	readline? ( sys-libs/readline )
	gmp? ( dev-libs/gmp )
	accessibility? ( app-accessibility/flite )
	gtk?  ( sci-visualization/gnuplot[gd]
			media-libs/gd[png]
			x11-libs/gtk+:2 )
	gnome? ( sci-visualization/gnuplot[gd]
			 media-libs/gd[png]
			 gnome-base/libgnomeui
			 gnome-base/libgnomeprint:2.2
			 gnome-base/libgnomeprintui:2.2
			 gnome-base/gconf:2 )
	R? ( dev-lang/R )
	sourceview? ( x11-libs/gtksourceview )
	odbc? ( dev-db/unixODBC )
	emacs? ( virtual/emacs )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

SITEFILE=50${PN}-gentoo.el

pkg_setup() {
	if use openmp &&
		[[ $(tc-getCC)$ == *gcc* ]] &&
		( [[ $(gcc-major-version)$(gcc-minor-version) -lt 42 ]] ||
			! has_version sys-devel/gcc[openmp] )
	then
		ewarn "You are using gcc and OpenMP is only available with gcc >= 4.2 "
		die "Need an OpenMP capable compiler"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.7.5-locale.patch \
		"${FILESDIR}"/${P}-ldflags.patch
	# fix parallel make reported upstream
	sed -i \
		-e 's/make -C/$(MAKE) -C/g' \
		$(find . -name Makefile.in) || die
}

src_configure() {
	local myconf
	if use gtk; then
		myconf="--enable-gui"
		myconf="${myconf} $(use_with sourceview gtksourceview)"
		myconf="${myconf} $(use_with gnome)"
	else
		myconf="--disable-gui --without-gnome --without-gtksourceview"
	fi

	econf \
		--with-mpfr \
		$(use_enable nls) \
		$(use_enable openmp) \
		$(use_with readline) \
		$(use_with gmp) \
		$(use_with odbc) \
		$(use_with accessibility audio) \
		$(use_with R libR) \
		${myconf} \
		LAPACK_LIBS="$(pkg-config --libs lapack)"
}

src_compile() {
	emake || die "emake failed"
	if use emacs; then
		elisp-compile utils/emacs/gretl.el || die "elisp-compile failed"
	fi
}

src_install() {
	if use gnome; then
		gnome2_src_install gnome_prefix="${D}"/usr svprefix="${D}usr"
	else
		einstall svprefix="${D}usr"
	fi
	if use gtk && ! use gnome; then
		doicon gnome/gretl.png
		make_desktop_entry gretl_x11 gretl
	fi
	if use emacs; then
		elisp-install ${PN} utils/emacs/gretl.{el,elc} \
			|| die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" \
			|| die "elisp-site-file-install failed"
	fi
	dodoc README README.audio ChangeLog CompatLog
}

pkg_postinst() {
	if use emacs; then
		elisp-site-regen
		elog "To begin using gretl-mode for all \".inp\" files that you edit,"
		elog "add the following line to your \"~/.emacs\" file:"
		elog "  (add-to-list 'auto-mode-alist '(\"\\\\.inp\\\\'\" . gretl-mode))"
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
}