[gentoo-commits] gentoo-x86 commit in games-emulation/dolphin: dolphin-9999.ebuild dolphin-4.0.2-r6.ebuild ChangeLog dolphin-4.0.2-r5.ebuild

[Devan Franchini (twitch153)]

twitch153    15/04/30 22:42:32

  Modified:             dolphin-9999.ebuild ChangeLog
  Added:                dolphin-4.0.2-r6.ebuild
  Removed:              dolphin-4.0.2-r5.ebuild
  Log:
  Removes unnecessary webkit USE flag dependency for wxGTK
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

Revision  Changes    Path
1.25                 games-emulation/dolphin/dolphin-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild?r1=1.24&r2=1.25

Index: dolphin-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- dolphin-9999.ebuild	26 Apr 2015 19:36:46 -0000	1.24
+++ dolphin-9999.ebuild	30 Apr 2015 22:42:32 -0000	1.25
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild,v 1.24 2015/04/26 19:36:46 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/dolphin-9999.ebuild,v 1.25 2015/04/30 22:42:32 twitch153 Exp $
 
 EAPI=5
 
@@ -50,7 +50,7 @@
 	media-libs/freetype
 	media-libs/libsoundtouch
 	>=sys-devel/gcc-4.6.0
-	x11-libs/wxGTK:${WX_GTK_VER}[webkit]
+	x11-libs/wxGTK:${WX_GTK_VER}
 	"
 
 pkg_pretend() {



1.35                 games-emulation/dolphin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/dolphin/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	26 Apr 2015 19:36:46 -0000	1.34
+++ ChangeLog	30 Apr 2015 22:42:32 -0000	1.35
@@ -1,6 +1,12 @@
 # ChangeLog for games-emulation/dolphin
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/ChangeLog,v 1.34 2015/04/26 19:36:46 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/ChangeLog,v 1.35 2015/04/30 22:42:32 twitch153 Exp $
+
+*dolphin-4.0.2-r6 (30 Apr 2015)
+
+  30 Apr 2015; Devan Franchini <twitch153@g.o> +dolphin-4.0.2-r6.ebuild,
+  -dolphin-4.0.2-r5.ebuild, dolphin-9999.ebuild:
+  Removes unnecessary webkit USE flag dependency for wxGTK
 
 *dolphin-4.0.2-r5 (26 Apr 2015)
 



1.1                  games-emulation/dolphin/dolphin-4.0.2-r6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/dolphin-4.0.2-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/dolphin/dolphin-4.0.2-r6.ebuild?rev=1.1&content-type=text/plain

Index: dolphin-4.0.2-r6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/dolphin/dolphin-4.0.2-r6.ebuild,v 1.1 2015/04/30 22:42:32 twitch153 Exp $

EAPI=5

WX_GTK_VER="3.0"

inherit cmake-utils eutils pax-utils toolchain-funcs versionator wxwidgets games

SRC_URI="https://github.com/${PN}-emu/${PN}/archive/${PV}.zip -> ${P}.zip"
KEYWORDS="~amd64"

DESCRIPTION="Gamecube and Wii game emulator"
HOMEPAGE="https://www.dolphin-emu.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="alsa ao bluetooth doc ffmpeg +lzo openal opengl openmp portaudio pulseaudio"

RESTRICT="mirror"

RDEPEND=">=media-libs/glew-1.6
	<media-libs/libsfml-2.0
	>=net-libs/miniupnpc-1.8
	media-libs/libsdl2[haptic,joystick]
	sys-libs/readline:=
	x11-libs/libXext
	x11-libs/libXrandr
	alsa? ( media-libs/alsa-lib )
	ao? ( media-libs/libao )
	bluetooth? ( net-wireless/bluez )
	ffmpeg? ( virtual/ffmpeg
		!!>=media-video/libav-10 )
	lzo? ( dev-libs/lzo )
	openal? ( media-libs/openal )
	opengl? ( virtual/opengl )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	"
DEPEND="${RDEPEND}
	app-arch/zip
	media-gfx/nvidia-cg-toolkit
	media-libs/freetype
	media-libs/libsoundtouch
	>=sys-devel/gcc-4.6.0
	x11-libs/wxGTK:${WX_GTK_VER}
	"

pkg_pretend() {

	local ver=4.6.0
	local msg="${PN} needs at least GCC ${ver} set to compile."

	if [[ ${MERGE_TYPE} != binary ]]; then
		if ! version_is_at_least ${ver} $(gcc-fullversion); then
			eerror ${msg}
			die ${msg}
		fi
	fi

}

src_prepare() {

	# Remove automatic dependencies to prevent building without flags enabled.
	if use !alsa; then
		sed -i -e '/include(FindALSA/d' CMakeLists.txt || die
	fi
	if use !ao; then
		sed -i -e '/check_lib(AO/d' CMakeLists.txt || die
	fi
	if use !bluetooth; then
		sed -i -e '/check_lib(BLUEZ/d' CMakeLists.txt || die
	fi
	if use !openal; then
		sed -i -e '/include(FindOpenAL/d' CMakeLists.txt || die
	fi
	if use !portaudio; then
		sed -i -e '/CMAKE_REQUIRED_LIBRARIES portaudio/d' CMakeLists.txt || die
	fi
	if use !pulseaudio; then
		sed -i -e '/check_lib(PULSEAUDIO/d' CMakeLists.txt || die
	fi

	# Remove ALL the bundled libraries, aside from:
	# - SOIL: The sources are not public.
	# - Bochs-disasm: Don't know what it is.
	# - CLRun: Part of OpenCL
	# - polarssl: Currently fails the check as is.
	mv Externals/SOIL . || die
	mv Externals/Bochs_disasm . || die
	mv Externals/CLRun . || die
	mv Externals/polarssl . || die
	rm -r Externals/* || die
	mv polarssl Externals || die
	mv CLRun Externals || die
	mv Bochs_disasm Externals || die
	mv SOIL Externals || die
}

src_configure() {

	local mycmakeargs=(
		"-DDOLPHIN_WC_REVISION=${PV}"
		"-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}"
		"-Dprefix=${GAMES_PREFIX}"
		"-Ddatadir=${GAMES_DATADIR}/${PN}"
		"-Dplugindir=$(games_get_libdir)/${PN}"
		$( cmake-utils_use ffmpeg ENCODE_FRAMEDUMPS )
		$( cmake-utils_use openmp OPENMP )
	)

	cmake-utils_src_configure
}

src_compile() {

	cmake-utils_src_compile
}

src_install() {

	cmake-utils_src_install

	dodoc Readme.txt
	if use doc; then
		dodoc -r docs/ActionReplay docs/DSP docs/WiiMote
	fi

	doicon Source/Core/DolphinWX/resources/Dolphin.xpm
	make_desktop_entry "dolphin-emu" "Dolphin" "Dolphin" "Game;"

	prepgamesdirs
}

pkg_postinst() {
	# Add pax markings for hardened systems
	pax-mark -m "${EPREFIX}"/usr/games/bin/"${PN}"-emu

	if ! use portaudio; then
		ewarn "If you want microphone capabilities in dolphin-emu, rebuild with"
		ewarn "USE=\"portaudio\""
	fi
}