[gentoo-commits] gentoo-x86 commit in net-libs/aqbanking: ChangeLog aqbanking-5.0.21.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/01/06 10:05:59

  Modified:             ChangeLog
  Added:                aqbanking-5.0.21.ebuild
  Log:
  Version bump wrt #394911 by Hannan Sadar
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.91                 net-libs/aqbanking/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?r1=1.90&r2=1.91

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog	21 Aug 2011 20:02:18 -0000	1.90
+++ ChangeLog	6 Jan 2012 10:05:59 -0000	1.91
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/aqbanking
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.90 2011/08/21 20:02:18 hanno Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.91 2012/01/06 10:05:59 ssuominen Exp $
+
+*aqbanking-5.0.21 (06 Jan 2012)
+
+  06 Jan 2012; Samuli Suominen <ssuominen@g.o> +aqbanking-5.0.21.ebuild:
+  Version bump wrt #394911 by Hannan Sadar
 
 *aqbanking-5.0.14 (21 Aug 2011)
 



1.1                  net-libs/aqbanking/aqbanking-5.0.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.21.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.21.ebuild?rev=1.1&content-type=text/plain

Index: aqbanking-5.0.21.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.21.ebuild,v 1.1 2012/01/06 10:05:59 ssuominen Exp $

EAPI=4

DESCRIPTION="Generic Online Banking Interface"
HOMEPAGE="http://www.aquamaniac.de/aqbanking/"
SRC_URI="http://www.aquamaniac.de/sites/download/download.php?package=03&release=91&file=01&dummy=${P}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="chipcard debug doc examples gtk ofx"

RDEPEND=">=app-misc/ktoblzcheck-1.37
	>=dev-libs/gmp-5
	>=sys-libs/gwenhywfar-4.3.1[gtk?]
	virtual/libintl
	ofx? ( >=dev-libs/libofx-0.9.4 )
	chipcard? ( >=sys-libs/libchipcard-5.0.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext
	doc? ( app-doc/doxygen )"

MAKEOPTS="${MAKEOPTS} -j1" # 5.0.x fails with -j9 on quadcore

src_configure() {
	local backends="aqhbci aqnone aqpaypal"
	use ofx && backends="${backends} aqofxconnect"

	local mytest
	use gtk && mytest="--enable-gui-tests"

	econf \
		$(use_enable debug) \
		$(use_enable doc full-doc) \
		--with-backends="${backends}" \
		--with-docpath=/usr/share/doc/${PF}/apidoc \
		${mytest}
}

src_install() {
	emake DESTDIR="${D}" install

	rm -rf "${ED}"usr/share/doc/aq{banking,hbci,paypal}

	dodoc AUTHORS ChangeLog NEWS README TODO

	newdoc src/plugins/backends/aqhbci/tools/aqhbci-tool/README \
		README.aqhbci-tool
	newdoc src/plugins/backends/aqpaypal/tools/aqpaypal-tool/README \
		README.aqpaypal-tool

	if use examples; then
		docinto tutorials
		dodoc tutorials/*.{c,h} tutorials/README
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +
}