[gentoo-commits] gentoo-x86 commit in mail-filter/maildrop: ChangeLog maildrop-2.4.2.ebuild maildrop-2.1.0.ebuild maildrop-2.4.0.ebuild maildrop-2.0.4.ebuild

[Torsten Veller (tove)]

tove        10/02/25 08:28:22

  Modified:             ChangeLog
  Added:                maildrop-2.4.2.ebuild
  Removed:              maildrop-2.1.0.ebuild maildrop-2.4.0.ebuild
                        maildrop-2.0.4.ebuild
  Log:
  Version bump. Cleanup
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.95                 mail-filter/maildrop/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/maildrop/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/maildrop/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/maildrop/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/maildrop/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	16 Feb 2010 11:07:42 -0000	1.94
+++ ChangeLog	25 Feb 2010 08:28:21 -0000	1.95
@@ -1,6 +1,12 @@
 # ChangeLog for mail-filter/maildrop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/maildrop/ChangeLog,v 1.94 2010/02/16 11:07:42 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/maildrop/ChangeLog,v 1.95 2010/02/25 08:28:21 tove Exp $
+
+*maildrop-2.4.2 (25 Feb 2010)
+
+  25 Feb 2010; Torsten Veller <tove@g.o> -maildrop-2.0.4.ebuild,
+  -maildrop-2.1.0.ebuild, -maildrop-2.4.0.ebuild, +maildrop-2.4.2.ebuild:
+  Version bump. Cleanup
 
 *maildrop-2.4.1 (16 Feb 2010)
 



1.1                  mail-filter/maildrop/maildrop-2.4.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/maildrop/maildrop-2.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/maildrop/maildrop-2.4.2.ebuild?rev=1.1&content-type=text/plain

Index: maildrop-2.4.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/maildrop/maildrop-2.4.2.ebuild,v 1.1 2010/02/25 08:28:21 tove Exp $

EAPI=2

inherit eutils flag-o-matic autotools

DESCRIPTION="Mail delivery agent/filter"
[[ -z ${PV/?.?/}   ]] && SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
[[ -z ${PV/?.?.?/} ]] && SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
[[ -z ${SRC_URI}   ]] && SRC_URI="http://www.courier-mta.org/beta/${PN}/${P%%_pre}.tar.bz2"
HOMEPAGE="http://www.courier-mta.org/maildrop/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~s390 ~sh ~sparc ~x86"
IUSE="berkdb debug fam gdbm ldap mysql postgres authlib"

DEPEND="!mail-mta/courier
	net-mail/mailbase
	dev-libs/libpcre
	net-dns/libidn
	gdbm?     ( >=sys-libs/gdbm-1.8.0 )
	mysql?    ( net-libs/courier-authlib )
	postgres? ( net-libs/courier-authlib )
	ldap?     ( net-libs/courier-authlib )
	authlib?  ( net-libs/courier-authlib )
	fam?      ( virtual/fam )
	!gdbm? (
		berkdb? (
			>=sys-libs/db-3
		)
	)"
RDEPEND="${DEPEND}
	dev-lang/perl"
PROVIDE="virtual/mda"

S=${WORKDIR}/${P%%_pre}

src_prepare() {
#	epatch "${FILESDIR}"/${PN}-2.0.4-makedat.patch

	# Prefer gdbm over berkdb
	if use gdbm ; then
		use berkdb && elog "Both gdbm and berkdb selected. Using gdbm."
	elif use berkdb ; then
		epatch "${FILESDIR}"/${PN}-2.2.0-db4.patch
	fi

	if ! use fam ; then
		epatch "${FILESDIR}"/${PN}-1.8.1-disable-fam.patch
	fi

	eautoreconf
}

src_configure() {
	local myconf
	local mytrustedusers="apache dspam root mail fetchmail \
		daemon postmaster qmaild mmdf vmail alias"

	# These flags make maildrop cry
	replace-flags -Os -O2
	filter-flags -fomit-frame-pointer

	if use gdbm ; then
		myconf="${myconf} --with-db=gdbm"
	elif use berkdb ; then
		myconf="${myconf} --with-db=db"
	else
		myconf="${myconf} --without-db"
	fi

	if ! use mysql && ! use postgres && ! use ldap && ! use authlib ; then
		myconf="${myconf} --disable-authlib"
	fi

	econf \
		$(use_enable fam) \
		--disable-dependency-tracker \
		--with-devel \
		--disable-tempdir \
		--enable-syslog=1 \
		--enable-use-flock=1 \
		--enable-use-dotlock=1 \
		--enable-restrict-trusted=1 \
		--enable-trusted-users="${mytrustedusers}" \
		--enable-maildrop-uid=root \
		--enable-maildrop-gid=mail \
		--with-default-maildrop=./.maildir/ \
		--enable-sendmail=/usr/sbin/sendmail \
		--cache-file="${S}"/configuring.cache \
		${myconf}
}

src_install() {
	make DESTDIR="${D}" install || die

	fperms 4755 /usr/bin/maildrop

	dodoc AUTHORS ChangeLog INSTALL NEWS README \
		README.postfix UPGRADE maildroptips.txt || die

	dodir /usr/share/doc/${PF}
	mv "${D}"/usr/share/maildrop/html "${D}"/usr/share/doc/${PF}/

	dohtml {INSTALL,README,UPGRADE}.html || die

	insinto /etc
	doins "${FILESDIR}"/maildroprc || die
}