[gentoo-commits] gentoo-x86 commit in dev-java/icu4j: ChangeLog icu4j-4.0.1.1.ebuild

[Alistair Bush (ali_bush)]

ali_bush    09/11/03 08:21:19

  Modified:             ChangeLog
  Added:                icu4j-4.0.1.1.ebuild
  Log:
  Version Bump.
  (Portage version: 2.1.7.1/cvs/Linux x86_64)

Revision  Changes    Path
1.32                 dev-java/icu4j/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	16 May 2009 22:21:03 -0000	1.31
+++ ChangeLog	3 Nov 2009 08:21:18 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/icu4j
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v 1.31 2009/05/16 22:21:03 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/ChangeLog,v 1.32 2009/11/03 08:21:18 ali_bush Exp $
+
+*icu4j-4.0.1.1 (03 Nov 2009)
+
+  03 Nov 2009; Alistair Bush <ali_bush@g.o> +icu4j-4.0.1.1.ebuild:
+  Version Bump.
 
 *icu4j-4.2 (16 May 2009)
 



1.1                  dev-java/icu4j/icu4j-4.0.1.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/icu4j-4.0.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/icu4j/icu4j-4.0.1.1.ebuild?rev=1.1&content-type=text/plain

Index: icu4j-4.0.1.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/icu4j/icu4j-4.0.1.1.ebuild,v 1.1 2009/11/03 08:21:18 ali_bush Exp $

EAPI=2

# We currently download the Javadoc documentation.
# It could optionally be built using the Ant build file.
# testdata.jar and icudata.jar do not contain *.class files but *.res files
# These *.res data files are needed to built the final jar
# They do not need to be installed however as they will already be present in icu4j.jar

JAVA_PKG_IUSE="doc test source"

inherit java-pkg-2 java-ant-2 java-osgi

DESCRIPTION="A set of Java libraries providing Unicode and Globalization support."
MY_PV=${PV//./_}

SRC_URI="http://download.icu-project.org/files/${PN}/${PV}/${PN}-${MY_PV}-src.jar
	doc? ( http://download.icu-project.org/files/${PN}/${PV}/${PN}-${MY_PV}-docs.jar )"

HOMEPAGE="http://www.icu-project.org/"
LICENSE="icu"
SLOT="4"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE=""

RDEPEND=">=virtual/jre-1.4"

# build.xml does file version detection that fails for 1.7
# http://bugs.gentoo.org/show_bug.cgi?id=213555
DEPEND="test? ( =virtual/jdk-1.6* )
	!test? ( || ( =virtual/jdk-1.6* =virtual/jdk-1.5* =virtual/jdk-1.4* ) )
	app-arch/unzip"

RESTRICT="ia64? ( test )
	x86-fbsd? ( test )"
JAVA_PKG_WANT_SOURCE="1.4"
JAVA_PKG_WANT_TARGET="1.4"

S="${WORKDIR}"

src_unpack() {
	jar -xf "${DISTDIR}/${PN}-${MY_PV}-src.jar" || die "Failed to unpack"

	if use doc; then
		mkdir docs; cd docs
		jar -xf "${DISTDIR}/${PN}-${MY_PV}-docs.jar" || die "Failed to unpack docs"
	fi
}

src_compile() {
	# Classes extending CharsetICU not implementing Comparable
	# Breaks with ecj on jdk 1.5+, javac doesn't mind - Sun's hack?
	# Restricting to javac (didn't even care to try jikes) is better
	# than forcing 1.4
	java-pkg_force-compiler javac
	eant jar || die "Compile failed"
}

src_install() {
	java-osgi_newjar-fromfile "${PN}.jar" "${FILESDIR}/icu4j-4.0-manifest" \
		"International Components for Unicode for Java (ICU4J)"
	java-pkg_dojar "${PN}-charsets.jar"

	use doc && dohtml -r readme.html docs/*
	use source && java-pkg_dosrc src/*
}

# Tests only work with JDK-1.6, severe out of memory problems appear with 1.5

src_test() {
	eant check
}