[gentoo-commits] gentoo-x86 commit in app-office/texmaker: ChangeLog texmaker-3.5.ebuild

[Justin Lecher (jlec)]

jlec        12/08/26 09:48:24

  Modified:             ChangeLog
  Added:                texmaker-3.5.ebuild
  Log:
  app-office/texmaker: Version BUmp; #432476
  
  (Portage version: 2.2.0_alpha122/cvs/Linux x86_64)

Revision  Changes    Path
1.107                app-office/texmaker/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	8 Aug 2012 20:20:22 -0000	1.106
+++ ChangeLog	26 Aug 2012 09:48:24 -0000	1.107
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/texmaker
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.106 2012/08/08 20:20:22 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.107 2012/08/26 09:48:24 jlec Exp $
+
+*texmaker-3.5 (26 Aug 2012)
+
+  26 Aug 2012; Justin Lecher <jlec@g.o> +texmaker-3.5.ebuild,
+  +files/texmaker-3.5-hunspell.patch:
+  Version BUmp; #432476
 
   08 Aug 2012; Brent Baude <ranger@g.o> texmaker-3.3.4.ebuild:
   Marking texmaker-3.3.4 ppc for bug 427198



1.1                  app-office/texmaker/texmaker-3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-3.5.ebuild?rev=1.1&content-type=text/plain

Index: texmaker-3.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-3.5.ebuild,v 1.1 2012/08/26 09:48:24 jlec Exp $

EAPI=4

inherit base qt4-r2 versionator

# The upstream version numbering is bad, so we have to remove a dot in the
# minor version number
MAJOR="$(get_major_version)"
MINOR_1="$(($(get_version_component_range 2)/10))"
MINOR_2="$(($(get_version_component_range 2)%10))"
if [ ${MINOR_2} -eq "0" ] ; then
	MY_P="${PN}-${MAJOR}.${MINOR_1}"
else
	MY_P="${PN}-${MAJOR}.${MINOR_1}.${MINOR_2}"
fi

MY_P="${P}"

DESCRIPTION="A nice LaTeX-IDE"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE=""

S="${WORKDIR}/${MY_P}"

COMMON_DEPEND="
	app-text/poppler[qt4]
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/qt-gui:4
	x11-libs/qt-core:4
	x11-libs/qt-webkit:4
	app-text/hunspell"
RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-text/psutils
	app-text/ghostscript-gpl
	media-libs/netpbm"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/${P}-hunspell.patch
	"${FILESDIR}"/${PN}-3.3.3-qt48.patch
	)
src_configure() {
	eqmake4 \
		${PN}.pro \
		PREFIX="${EPREFIX}/usr" \
		DESKTOPDIR="${EPREFIX}/usr/share/applications" \
		ICONDIR="${EPREFIX}/usr/share/pixmaps"
}

src_install() {
	emake INSTALL_ROOT="${ED}" install

	insinto /usr/share/pixmaps/texmaker
	doins utilities/texmaker*.png
	doins utilities/texmaker.svg

	dodoc utilities/AUTHORS utilities/CHANGELOG.txt
}

pkg_postinst() {
	elog "A user manual with many screenshots is available at:"
	elog "${EPREFIX}/usr/share/${PN}/usermanual_en.html"
}