[gentoo-commits] gentoo-x86 commit in app-office/texmaker: texmaker-4.1.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        13/11/03 10:51:38

  Modified:             ChangeLog
  Added:                texmaker-4.1.ebuild
  Log:
  app-office/texmaker: Version BUmp, #490220
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.137                app-office/texmaker/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.137&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?rev=1.137&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/ChangeLog?r1=1.136&r2=1.137

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v
retrieving revision 1.136
retrieving revision 1.137
diff -u -r1.136 -r1.137
--- ChangeLog	26 Oct 2013 09:47:18 -0000	1.136
+++ ChangeLog	3 Nov 2013 10:51:38 -0000	1.137
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/texmaker
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.136 2013/10/26 09:47:18 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/ChangeLog,v 1.137 2013/11/03 10:51:38 jlec Exp $
+
+*texmaker-4.1 (03 Nov 2013)
+
+  03 Nov 2013; Justin Lecher <jlec@g.o> +texmaker-4.1.ebuild,
+  +files/texmaker-4.1-unbundle.patch:
+  Version BUmp, #490220
 
 *texmaker-4.0.4-r1 (26 Oct 2013)
 



1.1                  app-office/texmaker/texmaker-4.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/texmaker/texmaker-4.1.ebuild?rev=1.1&content-type=text/plain

Index: texmaker-4.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/texmaker/texmaker-4.1.ebuild,v 1.1 2013/11/03 10:51:38 jlec Exp $

EAPI=5

inherit qt4-r2 versionator

# The upstream version numbering is bad, so we have to remove a dot in the
# minor version number
MAJOR="$(get_major_version)"
MINOR_1="$(($(get_version_component_range 2)/10))"
MINOR_2="$(($(get_version_component_range 2)%10))"
if [ ${MINOR_2} -eq "0" ] ; then
	MY_P="${PN}-${MAJOR}.${MINOR_1}"
else
	MY_P="${PN}-${MAJOR}.${MINOR_1}.${MINOR_2}"
fi

MY_P="${P}"

DESCRIPTION="A nice LaTeX-IDE"
HOMEPAGE="http://www.xm1math.net/texmaker/"
SRC_URI="http://www.xm1math.net/texmaker/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE=""

S="${WORKDIR}/${MY_P}"

COMMON_DEPEND="
	app-text/hunspell
	app-text/poppler:=[qt4]
	sys-libs/zlib
	x11-libs/libX11
	x11-libs/libXext
	dev-qt/qtgui:4
	dev-qt/qtcore:4
	dev-qt/qtsingleapplication
	dev-qt/qtwebkit:4
"
RDEPEND="${COMMON_DEPEND}
	virtual/latex-base
	app-i18n/ibus-qt
	app-text/psutils
	app-text/ghostscript-gpl
	media-libs/netpbm"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

PATCHES=( "${FILESDIR}"/${P}-unbundle.patch )

DOCS=( utilities/AUTHORS utilities/CHANGELOG.txt )
HTML_DOCS=( doc/. )

src_prepare() {
	find singleapp hunspell -delete || die

	qt4-r2_src_prepare

	cat >> ${PN}.pro <<- EOF
	exists(texmakerx_my.pri):include(texmakerx_my.pri)
	EOF
	cp "${FILESDIR}"/texmakerx_my.pri . || die

	sed \
		-e '/^#include/s:hunspell/::g' \
		-e '/^#include/s:singleapp/::g' \
		-i *.cpp *.h || die
}

src_configure() {
	eqmake4 \
		${PN}.pro \
		PREFIX="${EPREFIX}/usr" \
		DESKTOPDIR="${EPREFIX}/usr/share/applications" \
		ICONDIR="${EPREFIX}/usr/share/pixmaps"
}

pkg_postinst() {
	elog "A user manual with many screenshots is available at:"
	elog "${EPREFIX}/usr/share/${PN}/usermanual_en.html"
}