[gentoo-commits] gentoo-x86 commit in app-crypt/gnupg: ChangeLog gnupg-2.0.11.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/03/21 23:34:16

  Modified:             ChangeLog
  Added:                gnupg-2.0.11.ebuild
  Log:
  Version bump (bug #261293).
  (Portage version: 13139-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.337                app-crypt/gnupg/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/gnupg/ChangeLog?rev=1.337&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/gnupg/ChangeLog?rev=1.337&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/gnupg/ChangeLog?r1=1.336&r2=1.337

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v
retrieving revision 1.336
retrieving revision 1.337
diff -u -r1.336 -r1.337
--- ChangeLog	15 Feb 2009 05:10:20 -0000	1.336
+++ ChangeLog	21 Mar 2009 23:34:16 -0000	1.337
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/gnupg
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.336 2009/02/15 05:10:20 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.337 2009/03/21 23:34:16 arfrever Exp $
+
+*gnupg-2.0.11 (21 Mar 2009)
+
+  21 Mar 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +gnupg-2.0.11.ebuild:
+  Version bump (bug #261293).
 
 *gnupg-2.0.10 (15 Feb 2009)
 



1.1                  app-crypt/gnupg/gnupg-2.0.11.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/gnupg/gnupg-2.0.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-crypt/gnupg/gnupg-2.0.11.ebuild?rev=1.1&content-type=text/plain

Index: gnupg-2.0.11.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.11.ebuild,v 1.1 2009/03/21 23:34:16 arfrever Exp $

inherit flag-o-matic toolchain-funcs

DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
HOMEPAGE="http://www.gnupg.org/"
SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="bzip2 caps doc ldap nls openct pcsc-lite static selinux smartcard"

COMMON_DEPEND_LIBS="
	>=dev-libs/pth-1.3.7
	>=dev-libs/libgcrypt-1.4
	>=dev-libs/libksba-1.0.2
	>=dev-libs/libgpg-error-1.4
	>=net-misc/curl-7.7.2
	bzip2? ( app-arch/bzip2 )
	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )
	openct? ( >=dev-libs/openct-0.5.0 )
	ldap? ( net-nds/openldap )"
COMMON_DEPEND_BINS="app-crypt/pinentry"

# existence of bins are checked during configure
DEPEND="${COMMON_DEPEND_LIBS}
	${COMMON_DEPEND_BINS}
	>=dev-libs/libassuan-1.0.4
	nls? ( sys-devel/gettext )
	doc? ( sys-apps/texinfo )"

RDEPEND="!static? ( ${COMMON_DEPEND_LIBS} )
	${COMMON_DEPEND_BINS}
	virtual/mta
	!app-crypt/gpg-agent
	!<=app-crypt/gnupg-2.0.1
	selinux? ( sec-policy/selinux-gnupg )
	nls? ( virtual/libintl )"

src_compile() {
	# 'USE=static' support was requested:
	# gnupg1: bug #29299
	# gnupg2: bug #159623
	use static && append-ldflags -static

	econf \
		--docdir="/usr/share/doc/${PF}" \
		--enable-symcryptrun \
		--enable-gpg \
		--enable-gpgsm \
		--enable-agent \
		$(use_enable bzip2) \
		$(use_enable smartcard scdaemon) \
		$(use_enable nls) \
		$(use_enable ldap) \
		$(use_enable static) \
		$(use_enable caps capabilities) \
		CC_FOR_BUILD=$(tc-getBUILD_CC)
	emake || die "emake failed"
	if use doc; then
		cd doc
		emake html || die "emake html failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc ChangeLog NEWS README THANKS TODO VERSION

	mv "${D}/usr/share/gnupg"/help* "${D}/usr/share/doc/${PF}"
	ecompressdir "/usr/share/doc/${P}"

	dosym gpg2 /usr/bin/gpg
	dosym gpgv2 /usr/bin/gpgv
	dosym gpg2keys_hkp /usr/libexec/gpgkeys_hkp
	dosym gpg2keys_finger /usr/libexec/gpgkeys_finger
	dosym gpg2keys_curl /usr/libexec/gpgkeys_curl
	use ldap && dosym gpg2keys_ldap /usr/libexec/gpgkeys_ldap
	echo ".so man1/gpg2.1" > "${D}/usr/share/man/man1/gpg.1"
	echo ".so man1/gpgv2.1" > "${D}/usr/share/man/man1/gpgv.1"

	use doc && dohtml doc/gnupg.html/* doc/*jpg doc/*png
}

pkg_postinst() {
	elog "If you wish to view images emerge:"
	elog "media-gfx/xloadimage, media-gfx/xli or any other viewer"
	elog "Remember to use photo-viewer option in configuration file to activate"
	elog "the right viewer"
}