[gentoo-commits] gentoo-x86 commit in dev-util/schroot: metadata.xml ChangeLog schroot-1.4.0.ebuild

[Jonathan Callen (abcd)]

abcd        10/01/31 22:40:12

  Modified:             metadata.xml ChangeLog
  Added:                schroot-1.4.0.ebuild
  Log:
  Bump schroot
  (Portage version: -svn/cvs/Linux i686)

Revision  Changes    Path
1.3                  dev-util/schroot/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/schroot/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	29 Dec 2009 17:54:42 -0000	1.2
+++ metadata.xml	31 Jan 2010 22:40:11 -0000	1.3
@@ -8,5 +8,6 @@
 </maintainer>
 <use>
   <flag name="dchroot">Enables the building of a wrapper named "dchroot", replacing <pkg>sys-apps/dchroot</pkg>.</flag>
+  <flag name="lvm">Enable support for chroots on LVM.</flag>
 </use>
 </pkgmetadata>



1.13                 dev-util/schroot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	29 Dec 2009 21:39:32 -0000	1.12
+++ ChangeLog	31 Jan 2010 22:40:11 -0000	1.13
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/schroot
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.12 2009/12/29 21:39:32 abcd Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.13 2010/01/31 22:40:11 abcd Exp $
+
+*schroot-1.4.0 (31 Jan 2010)
+
+  31 Jan 2010; Jonathan Callen <abcd@g.o> +schroot-1.4.0.ebuild,
+  +files/schroot-1.4.0-tests.patch, metadata.xml:
+  New upstream version
 
   29 Dec 2009; Jonathan Callen <abcd@g.o> schroot-1.2.3-r4.ebuild:
   Fix incorrect blocker



1.1                  dev-util/schroot/schroot-1.4.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.4.0.ebuild?rev=1.1&content-type=text/plain

Index: schroot-1.4.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/schroot-1.4.0.ebuild,v 1.1 2010/01/31 22:40:11 abcd Exp $

EAPI="2"
WANT_AUTOMAKE="1.11"

inherit autotools base pam

DESCRIPTION="Utility to execute commands in a chroot environment"
HOMEPAGE="http://packages.debian.org/source/sid/schroot"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.orig.tar.gz"

RESTRICT="mirror"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+dchroot debug doc lvm nls pam test"

COMMON_DEPEND="
	>=dev-libs/boost-1.39.0
	dev-libs/lockdev
	>=sys-apps/util-linux-2.16
	lvm? ( sys-fs/lvm2 )
	pam? ( sys-libs/pam )
"

DEPEND="${COMMON_DEPEND}
	doc? (
		app-doc/doxygen
		media-gfx/graphviz
	)
	nls? ( sys-devel/gettext )
	test? ( >=dev-util/cppunit-1.10.0 )
"
RDEPEND="${COMMON_DEPEND}
	sys-apps/debianutils
	dchroot? ( !sys-apps/dchroot )
	nls? ( virtual/libintl )
"

PATCHES=(
	"${FILESDIR}/${P}-tests.patch"
)

src_prepare() {
	base_src_prepare

	# Don't depend on cppunit unless we are testing
	use test || sed -i '/AM_PATH_CPPUNIT/d' configure.ac

	echo -e "Package: ${PN}\nVersion: ${PV}" > VERSION

	eautoreconf
}

src_configure() {
	root_tests=no
	use test && (( EUID == 0 )) && root_tests=yes
	econf \
		$(use_enable doc doxygen) \
		$(use_enable dchroot) \
		$(use_enable dchroot dchroot-dsa) \
		$(use_enable debug) \
		$(use_enable lvm lvm-snapshot) \
		$(use_enable nls) \
		$(use_enable pam) \
		--enable-block-device \
		--enable-loopback \
		--enable-uuid \
		--enable-root-tests=$root_tests \
		--enable-shared \
		--disable-static \
		--localstatedir=/var \
		--with-bash-completion-dir=/usr/share/bash-completion
}

src_test() {
	if [[ $root_tests == yes && $EUID -ne 0 ]]; then
		ewarn "Disabling tests because you are no longer root"
		return 0
	fi
	default
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	newinitd "${FILESDIR}"/schroot.initd schroot || die "installation of init.d script failed"
	newconfd "${FILESDIR}"/schroot.confd schroot || die "installation of conf.d file failed"

	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "installation of docs failed"
	if use doc; then
		docinto html/sbuild
		dohtml doc/sbuild/html/* || die "installation of html docs failed"
		docinto html/schroot
		dohtml doc/schroot/html/* || die "installation of html docs failed"
	fi

	if use pam; then
		rm -f "${D}"/etc/pam.d/schroot
		pamd_mimic_system schroot auth account session
	fi

	# Remove *.la files
	find "${D}" -name "*.la" -exec rm {} + || die "removal of *.la files failed"
}