[gentoo-commits] proj/kde:master commit in: kde-base/kde-l10n/

[Alexey Shvetsov]

commit:     074a999942c0f07d2f952883889089cdab9e4481
Author:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
AuthorDate: Mon May 30 20:55:50 2011 +0000
Commit:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
CommitDate: Mon May 30 20:55:50 2011 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=074a9999

[kde-base] Add kde-l10n

---
 kde-base/kde-l10n/kde-l10n-4.6.80.ebuild |   91 ++++++++++++++++++++++++++++++
 1 files changed, 91 insertions(+), 0 deletions(-)

diff --git a/kde-base/kde-l10n/kde-l10n-4.6.80.ebuild b/kde-base/kde-l10n/kde-l10n-4.6.80.ebuild
new file mode 100644
index 0000000..57e5a61
--- /dev/null
+++ b/kde-base/kde-l10n/kde-l10n-4.6.80.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.6.3-r1.ebuild,v 1.2 2011/05/17 05:44:19 maekke Exp $
+
+EAPI="3"
+
+inherit kde4-base
+
+DESCRIPTION="KDE internationalization package"
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2"
+
+DEPEND="
+	sys-devel/gettext
+"
+RDEPEND="!<kde-misc/konq-plugins-4.6"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+handbook"
+
+# /usr/portage/distfiles $ ls -1 kde-l10n-*-${PV}.* |sed -e 's:-${PV}.tar.bz2::' -e 's:kde-l10n-::' |tr '\n' ' '
+MY_LANGS="ar bg ca ca@valencia cs da de el en_GB es et eu fi fr ga gl gu he hi
+hr hu ia id is it ja kk km kn ko lt lv nb nds nl nn pa pl pt pt_BR ro ru sk
+sl sr sv th tr uk wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.bz2 )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	# For EAPI >= 3, or if not using .tar.xz archives:
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="${PN}-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+			fi
+		done
+	fi
+}
+
+src_prepare() {
+	# Upstream added kdepim-runtime translations by mistake and does not want to
+	# make a new tarball, bug 366353
+
+	find "${S}" -name CMakeLists.txt -type f \
+		-exec sed -i -e 's:add_subdirectory(kdepim-runtime):# no kdepim-runtime:g' {} +
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook docs)
+	)
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_test() {
+	[[ -n ${A} ]] && kde4-base_src_test
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}