[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-keyring: ChangeLog gnome-keyring-3.2.2.ebuild gnome-keyring-3.0.3-r200.ebuild gnome-keyring-3.0.3-r300.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/11/17 06:09:12

  Modified:             ChangeLog
  Added:                gnome-keyring-3.2.2.ebuild
  Removed:              gnome-keyring-3.0.3-r200.ebuild
                        gnome-keyring-3.0.3-r300.ebuild
  Log:
  Bump, drop old. Notable changes: no longer autostarts in xfce and lxde (they don't support the new gnome-keyring dbus API), various bugfixes. Restrict tests since there seems to be no good way to reliably run them from portage.
  
  (Portage version: 2.2.0_alpha74/cvs/Linux x86_64)

Revision  Changes    Path
1.215                gnome-base/gnome-keyring/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?rev=1.215&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?rev=1.215&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog	30 Oct 2011 15:58:01 -0000	1.214
+++ ChangeLog	17 Nov 2011 06:09:12 -0000	1.215
@@ -1,6 +1,16 @@
 # ChangeLog for gnome-base/gnome-keyring
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v 1.214 2011/10/30 15:58:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/ChangeLog,v 1.215 2011/11/17 06:09:12 tetromino Exp $
+
+*gnome-keyring-3.2.2 (17 Nov 2011)
+
+  17 Nov 2011; Alexandre Rostovtsev <tetromino@g.o>
+  -files/gnome-keyring-3.0.2-automagic-libcap.patch,
+  -gnome-keyring-3.0.3-r200.ebuild, -gnome-keyring-3.0.3-r300.ebuild,
+  +gnome-keyring-3.2.2.ebuild:
+  Bump, drop old. Notable changes: no longer autostarts in xfce and lxde (they
+  don't support the new gnome-keyring dbus API), various bugfixes. Restrict
+  tests since there seems to be no good way to reliably run them from portage.
 
   30 Oct 2011; Raúl Porcel <armin76@g.o>
   gnome-keyring-2.32.1-r1.ebuild:



1.1                  gnome-base/gnome-keyring/gnome-keyring-3.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-3.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-3.2.2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-keyring-3.2.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-keyring/gnome-keyring-3.2.2.ebuild,v 1.1 2011/11/17 06:09:12 tetromino Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit gnome2 multilib pam virtualx

DESCRIPTION="Password and keyring managing daemon"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
IUSE="+caps debug doc pam test"
KEYWORDS="~amd64 ~mips ~sh ~x86 ~x86-fbsd ~amd64-linux ~sparc-solaris ~x86-linux ~x86-solaris"

# USE=valgrind is probably not a good idea for the tree
RDEPEND=">=dev-libs/glib-2.25:2
	>=x11-libs/gtk+-2.90.0:3
	>=app-crypt/p11-kit-0.6
	app-misc/ca-certificates
	>=dev-libs/libgcrypt-1.2.2
	>=dev-libs/libtasn1-1
	>=sys-apps/dbus-1.0
	caps? ( sys-libs/libcap-ng )
	pam? ( virtual/pam )
"
#	valgrind? ( dev-util/valgrind )
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/gtk-doc-am-1.9
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.9
	doc? ( >=dev-util/gtk-doc-1.9 )"
PDEPEND=">=gnome-base/libgnome-keyring-3.1.92"
# eautoreconf needs:
#	>=dev-util/gtk-doc-am-1.9

# FIXME: tests are flaky and write to /tmp (instead of TMPDIR)
RESTRICT="test"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"
	G2CONF="${G2CONF}
		$(use_enable debug)
		$(use_enable test tests)
		$(use_with caps libcap-ng)
		$(use_enable pam)
		$(use_with pam pam-dir $(getpam_mod_dir))
		--with-root-certs=${EPREFIX}/etc/ssl/certs/
		--enable-ssh-agent
		--enable-gpg-agent
		--disable-update-mime"
#		$(use_enable valgrind)
}

src_prepare() {
	# Disable gcr tests due to weirdness with opensc
	# ** WARNING **: couldn't load PKCS#11 module: /usr/lib64/pkcs11/gnome-keyring-pkcs11.so: Couldn't initialize module: The device was removed or unplugged
	sed -e 's/^\(SUBDIRS = \.\)\(.*\)/\1/' \
		-i gcr/Makefile.* || die "sed failed"

	gnome2_src_prepare
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	Xemake check
}

pkg_postinst() {
	use caps && fcaps 0:0 755 cap_ipc_lock "${ROOT}"/usr/bin/gnome-keyring-daemon

	gnome2_pkg_postinst
}

# borrowed from GSoC2010_Gentoo_Capabilities by constanze and Flameeyes
# @FUNCTION: fcaps
# @USAGE: fcaps {uid:gid} {file-mode} {cap1[,cap2,...]} {file}
# @RETURN: 0 if all okay; non-zero if failure and fallback
# @DESCRIPTION:
# fcaps sets the specified capabilities in the effective and permitted set of
# the given file. In case of failure fcaps sets the given file-mode.
fcaps() {
	local uid_gid=$1
	local perms=$2
	local capset=$3
	local path=$4
	local res

	chmod $perms $path && \
	chown $uid_gid $path
	res=$?

	use caps || return $res

	#set the capability
	setcap "$capset=ep" "$path" &> /dev/null
	#check if the capabilitiy got set correctly
	setcap -v "$capset=ep" "$path" &> /dev/null
	res=$?

	if [ $res -ne 0 ]; then
		ewarn "Failed to set capabilities. Probable reason is missed kernel support."
		ewarn "Kernel must have SECURITY_FILE_CAPABILITIES, and <FS>_FS_SECURITY"
		ewarn "enabled (e.g. EXT3_FS_SECURITY) where <FS> is the filesystem to store"
		ewarn "${path}"
		ewarn
		ewarn "Falling back to suid now..."
		chmod u+s ${path}
	fi
	return $res
}