[gentoo-dev] [PATCH 5/5] sys-fs/ncdu: add 2.6-r1

[Eric Joldasov <bratishkaerik@landless-city.net>]

Now uses "zig-build" eclass.

Signed-off-by: Eric Joldasov <bratishkaerik@landless-city.net>
---
 sys-fs/ncdu/ncdu-2.6-r1.ebuild | 50 ++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 sys-fs/ncdu/ncdu-2.6-r1.ebuild

diff --git a/sys-fs/ncdu/ncdu-2.6-r1.ebuild b/sys-fs/ncdu/ncdu-2.6-r1.ebuild
new file mode 100644
index 000000000000..6fb3c76328cc
--- /dev/null
+++ b/sys-fs/ncdu/ncdu-2.6-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/yoranheling.asc
+# Upstream states 0.12.x and 0.13.x support,
+# but eclass supports only one slot.
+ZIG_SLOT="0.13"
+inherit verify-sig zig-build
+
+DESCRIPTION="NCurses Disk Usage"
+HOMEPAGE="https://dev.yorhel.nl/ncdu"
+SRC_URI="
+	https://dev.yorhel.nl/download/${P}.tar.gz
+	verify-sig? ( https://dev.yorhel.nl/download/${P}.tar.gz.asc )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-yorhel )"
+DEPEND="
+	app-arch/zstd
+	sys-libs/ncurses:=[unicode(+)]
+"
+RDEPEND="${DEPEND}"
+
+DOCS=("README.md" "ChangeLog")
+
+src_unpack() {
+	verify-sig_src_unpack
+}
+
+src_configure() {
+	local my_zbs_args=(
+		-Dpie=true
+		# Upstream recommends this default:
+		--release=fast
+	)
+
+	zig-build_src_configure
+}
+
+src_install() {
+	zig-build_src_install
+
+	doman ncdu.1
+}
-- 
2.47.0