Re: [gentoo-proxy-maint] [PATCH] www-plugins/passff-host: Fix for firefox-bin with no-symlink-lib

[Michał Górny]

On Fri, 2019-06-28 at 08:48 +0200, Haelwenn (lanodan) Monnier wrote:
> Closes: https://bugs.gentoo.org/show_bug.cgi?id=687746
> Signed-off-by: Haelwenn (lanodan) Monnier <contact@×××××××××.me>
> ---
>  ...sff-host-1.2.0.ebuild => passff-host-1.2.0-r1.ebuild} | 9 ++++++++-
>  1 file changed, 8 insertions(+), 1 deletion(-)
>  rename www-plugins/passff-host/{passff-host-1.2.0.ebuild => passff-host-1.2.0-r1.ebuild} (84%)
>
> diff --git a/www-plugins/passff-host/passff-host-1.2.0.ebuild b/www-plugins/passff-host/passff-host-1.2.0-r1.ebuild
> similarity index 84%
> rename from www-plugins/passff-host/passff-host-1.2.0.ebuild
> rename to www-plugins/passff-host/passff-host-1.2.0-r1.ebuild
> index f42fb96ba19..75bebf643b8 100644
> --- a/www-plugins/passff-host/passff-host-1.2.0.ebuild
> +++ b/www-plugins/passff-host/passff-host-1.2.0-r1.ebuild
> @@ -1,52 +1,59 @@
>  # Copyright 2018-2019 Gentoo Authors
>  # Distributed under the terms of the GNU General Public License v2
>
>  EAPI=7
>
>  PYTHON_COMPAT=( python3_5 python3_6 python3_7 )
>
>  inherit python-single-r1
>
>  DESCRIPTION="Host app for the PassFF WebExtension"
>  HOMEPAGE="https://github.com/passff/passff-host"
>
>  SRC_URI="
>  	https://github.com/passff/passff-host/releases/download/${PV}/passff.py -> ${P}.py
>  	https://github.com/passff/passff-host/releases/download/${PV}/passff.json -> ${P}.json
>  "
>
>  LICENSE="GPL-2"
>  SLOT="0"
>  KEYWORDS="~amd64 ~x86"
>  IUSE="chrome chromium firefox vivaldi"
>  REQUIRED_USE="|| ( chrome chromium firefox vivaldi )"
>
>  S="${WORKDIR}"
>
>  src_unpack() {
>  	cp "${DISTDIR}/${P}.json" . || die
>  	cp "${DISTDIR}/${P}.py" . || die
>  }
>
>  src_prepare() {
>  	default
>  	python_fix_shebang "${P}.py"
>  }
>
>  src_install() {
>  	local target_dirs=()
>
>  	use chrome   && target_dirs+=( "/etc/opt/chrome/native-messaging-hosts" )
>  	use chromium && target_dirs+=( "/etc/chromium/native-messaging-hosts" )
> -	use firefox  && target_dirs+=( "/usr/$(get_libdir)/mozilla/native-messaging-hosts" )
> +	if use firefox; then
> +		target_dirs+=( "/usr/$(get_libdir)/mozilla/native-messaging-hosts" )
> +
> +		# firefox-bin compatibility
> +		if [[ "$(get_libdir)" != "lib" ]]; then
> +			target_dirs+=( "/usr/lib/mozilla/native-messaging-hosts" )
> +		fi
> +	fi

Wouldn't this break the migration?  I think this will cause unsymlink-
lib to detect collision if this package is installed before the switch.

>  	use vivaldi  && target_dirs+=( "/etc/vivaldi/native-messaging-hosts" )
>
>  	for target_dir in "${target_dirs[@]}"; do
>  		sed "s;PLACEHOLDER;${target_dir}/passff.py;g" "${P}.json" > "passff.json" || die
>
>  		insinto "${target_dir}"
>  		doins passff.json
>  		exeinto "${target_dir}"
>  		newexe "${P}.py" passff.py
>  	done
>  }

-- 
Best regards,
Michał Górny