[gentoo-proxy-maint] [PATCH] net-nntp/tin: drop libpcre support in 2.6.2

[Anna Vyalkova]

Signed-off-by: Anna Vyalkova <cyber+gentoo@×××××.in>
---
 net-nntp/tin/metadata.xml                             |  1 -
 .../tin/{tin-2.6.2.ebuild => tin-2.6.2-r1.ebuild}     | 11 +++++------
 2 files changed, 5 insertions(+), 7 deletions(-)
 rename net-nntp/tin/{tin-2.6.2.ebuild => tin-2.6.2-r1.ebuild} (91%)

diff --git a/net-nntp/tin/metadata.xml b/net-nntp/tin/metadata.xml
index 2273dcd0ef..99b4b39ce6 100644
--- a/net-nntp/tin/metadata.xml
+++ b/net-nntp/tin/metadata.xml
@@ -1,14 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<!-- maintainer-needed -->
 	<upstream>
 		<doc>http://www.tin.org/bin/man.cgi?section=1&amp;topic=tin</doc>
 	</upstream>
 	<use>
 		<flag name="cancel-locks">Enable Cancel-Lock header functionality</flag>
 		<flag name="gpg">Enable <pkg>app-crypt/gnupg</pkg> support</flag>
 		<flag name="libtls" restrict="&gt;=net-nntp/tin-2.6.2">Prefer <pkg>dev-libs/libretls</pkg> as SSL/TLS provider (ineffective with USE=-ssl)</flag>
-		<flag name="pcre2" restrict="&gt;=net-nntp/tin-2.6.2">Use <pkg>dev-libs/libpcre2</pkg> instead of <pkg>dev-libs/libpcre</pkg></flag>
 	</use>
 </pkgmetadata>
diff --git a/net-nntp/tin/tin-2.6.2.ebuild b/net-nntp/tin/tin-2.6.2-r1.ebuild
similarity index 91%
rename from net-nntp/tin/tin-2.6.2.ebuild
rename to net-nntp/tin/tin-2.6.2-r1.ebuild
index 50345f36be..b5e39382f9 100644
--- a/net-nntp/tin/tin-2.6.2.ebuild
+++ b/net-nntp/tin/tin-2.6.2-r1.ebuild
@@ -1,116 +1,115 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 inherit optfeature toolchain-funcs
 
 DESCRIPTION="A threaded NNTP and spool based UseNet newsreader"
 HOMEPAGE="http://www.tin.org/"
 SRC_URI="ftp://ftp.tin.org/pub/news/clients/tin/stable/${P}.tar.xz"
 
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="cancel-locks debug gnutls gpg libtls nls +pcre2 sasl socks5 ssl"
+IUSE="cancel-locks debug gnutls gpg libtls nls sasl socks5 ssl"
 
 RDEPEND="
 	dev-libs/icu:=
+	dev-libs/libpcre2:=
 	dev-libs/uulib
 	sys-libs/ncurses:=
 	virtual/libiconv
 	cancel-locks? ( >=net-libs/canlock-3.0:= )
 	gpg? ( app-crypt/gnupg )
 	nls? ( virtual/libintl )
-	pcre2? ( dev-libs/libpcre2:= )
-	!pcre2? ( dev-libs/libpcre:3 )
 	sasl? ( virtual/gsasl )
 	socks5? ( net-proxy/dante )
 	ssl? (
 		gnutls? ( net-libs/gnutls:= )
 		!gnutls? (
 			libtls? ( dev-libs/libretls:= )
 			!libtls? ( dev-libs/openssl:= )
 		)
 	)
 "
 DEPEND="${RDEPEND}"
 BDEPEND="
 	app-alternatives/yacc
+	dev-libs/libpcre2
 	virtual/pkgconfig
 	nls? ( sys-devel/gettext )
 "
 
 PATCHES=( "${FILESDIR}"/${P}-gnutls.patch )
 
 DOCS=(
 	README{,.MAC,.WIN}
 	doc/{CHANGES{,.old},CREDITS,TODO,WHATSNEW,filtering}
 )
 
 src_configure() {
 	tc-export AR CC RANLIB
 	tc-export_build_env
 
 	local myeconfargs=(
 		$(use_enable cancel-locks)
 		$(use_with cancel-locks canlock)
 
-		$(use_with pcre2 pcre2-config)
-		$(use_with !pcre2 pcre "${ESYSROOT}"/usr)
-
 		$(use_enable debug)
 		$(use_enable gpg pgp-gpg)
 		$(use_enable nls)
 		$(use_with socks5 socks)
 		--disable-mime-strict-charset
 		--enable-nntp
 		--enable-prototypes
+		--without-pcre
+		--with-pcre2-config
 		--with-coffee # easter egg :)
 		--with-nntp-default-server="${TIN_DEFAULT_SERVER:-${NNTPSERVER:-news.gmane.io}}"
 		--with-screen=ncursesw
 	)
 
 	if use ssl; then
 		if use gnutls; then
 			myeconfargs+=( --with-nntps=gnutls )
 		elif use libtls; then
 			myeconfargs+=( --with-nntps=libtls )
 		else
 			myeconfargs+=( --with-nntps=openssl )
 		fi
 	fi
 
 	myeconfargs+=(
 		# set default paths for utilities
 		--with-editor="${EPREFIX}"/usr/libexec/editor
 		--with-gpg="${EPREFIX}"/usr/bin/gpg
 		--with-ispell="${EPREFIX}"/usr/bin/aspell
 		--with-mailer="${EPREFIX}"/bin/mail
 		--with-sum="${EPREFIX}"/usr/bin/sum
 
 		# set default paths for directories
 		--with-libdir="${EPREFIX}"/var/lib/news
 		--with-spooldir="${EPREFIX}"/var/spool/news
 	)
 
 	econf "${myeconfargs[@]}"
 }
 
 src_compile() {
 	# To build from the root dir you have to call `make build`, not just `make`.
 	emake build
 }
 
 src_install() {
 	default
 
 	emake DESTDIR="${D}" install_sysdefs
 	emake -C src DESTDIR="${D}" install_nls_man
 
 	dodoc doc/{*.sample,*.txt}
 }
 
 pkg_postinst() {
 	optfeature "spell checker support" app-text/aspell
 }
-- 
2.39.0