[gentoo-python] [PATCH 8/8] Support python-exec:2.

[Michał Górny]

---
 gx86/eclass/distutils-r1.eclass     |  8 +++++---
 gx86/eclass/python-r1.eclass        | 36 +++++++++++++++++++++++++--------
 gx86/eclass/python-single-r1.eclass |  8 +++++++-
 gx86/eclass/python-utils-r1.eclass  | 40 ++++++++++++++++++++++++++++++++++---
 4 files changed, 77 insertions(+), 15 deletions(-)

diff --git a/gx86/eclass/distutils-r1.eclass b/gx86/eclass/distutils-r1.eclass
index 0517bbb..1e04bd4 100644
--- a/gx86/eclass/distutils-r1.eclass
+++ b/gx86/eclass/distutils-r1.eclass
@@ -428,9 +428,11 @@ _distutils-r1_wrap_scripts() {
 		if [[ ${shebang} == '#!'*${EPYTHON}* ]]; then
 			debug-print "${FUNCNAME}: matching shebang: ${shebang}"
 
-			local newfn=${basename}-${EPYTHON}
-			debug-print "${FUNCNAME}: renaming to /usr/bin/${newfn}"
-			mv "${f}" "${ED%/}/usr/bin/${newfn}" || die
+			if ! _python_want_python_exec2; then
+				local newfn=${basename}-${EPYTHON}
+				debug-print "${FUNCNAME}: renaming to /usr/bin/${newfn}"
+				mv "${f}" "${ED%/}/usr/bin/${newfn}" || die
+			fi
 
 			debug-print "${FUNCNAME}: installing wrapper at /usr/bin/${basename}"
 			_python_symlink_wrapper "${ED%/}/usr/bin/${basename}"
diff --git a/gx86/eclass/python-r1.eclass b/gx86/eclass/python-r1.eclass
index d1b2143..f146f91 100644
--- a/gx86/eclass/python-r1.eclass
+++ b/gx86/eclass/python-r1.eclass
@@ -122,7 +122,7 @@ fi
 #
 # Example value:
 # @CODE
-# dev-python/python-exec:0
+# dev-python/python-exec:=
 # python_targets_python2_6? ( dev-lang/python:2.6[gdbm] )
 # python_targets_python2_7? ( dev-lang/python:2.7[gdbm] )
 # @CODE
@@ -203,7 +203,13 @@ _python_set_globals() {
 	# but no point in making this overcomplex, BDEP doesn't hurt anyone
 	# 2) python-exec should be built with all targets forced anyway
 	# but if new targets were added, we may need to force a rebuild
-	PYTHON_DEPS+="dev-python/python-exec:0[${PYTHON_USEDEP}]"
+	# 3) use whichever python-exec slot installed in EAPI 5. For EAPI 4,
+	# just fix :0 for now since := deps are not supported.
+	if [[ ${EAPI} != 4 ]]; then
+		PYTHON_DEPS+="dev-python/python-exec:=[${PYTHON_USEDEP}]"
+	else
+		PYTHON_DEPS+="dev-python/python-exec:0[${PYTHON_USEDEP}]"
+	fi
 }
 _python_set_globals
 
@@ -742,12 +748,26 @@ python_replicate_script() {
 	debug-print-function ${FUNCNAME} "${@}"
 
 	_python_replicate_script() {
-		local f
-		for f in "${files[@]}"; do
-			cp -p "${f}" "${f}-${EPYTHON}" || die
-		done
-		_python_rewrite_shebang "${EPYTHON}" \
-			"${files[@]/%/-${EPYTHON}}"
+		if _python_want_python_exec2; then
+			local PYTHON_SCRIPTDIR
+			python_export PYTHON_SCRIPTDIR
+
+			(
+				exeinto "${PYTHON_SCRIPTDIR#${EPREFIX}}"
+				doexe "${files[@]}"
+			)
+
+			_python_rewrite_shebang "${EPYTHON}" \
+				"${files[@]/*\//${D%/}/${PYTHON_SCRIPTDIR}/}"
+		else
+			local f
+			for f in "${files[@]}"; do
+				cp -p "${f}" "${f}-${EPYTHON}" || die
+			done
+
+			_python_rewrite_shebang "${EPYTHON}" \
+				"${files[@]/%/-${EPYTHON}}"
+		fi
 	}
 
 	local files=( "${@}" )
diff --git a/gx86/eclass/python-single-r1.eclass b/gx86/eclass/python-single-r1.eclass
index 2b099c3..46786ea 100644
--- a/gx86/eclass/python-single-r1.eclass
+++ b/gx86/eclass/python-single-r1.eclass
@@ -193,7 +193,13 @@ _python_single_set_globals() {
 	# but no point in making this overcomplex, BDEP doesn't hurt anyone
 	# 2) python-exec should be built with all targets forced anyway
 	# but if new targets were added, we may need to force a rebuild
-	PYTHON_DEPS+="dev-python/python-exec:0[${PYTHON_USEDEP}]"
+	# 3) use whichever python-exec slot installed in EAPI 5. For EAPI 4,
+	# just fix :0 for now since := deps are not supported.
+	if [[ ${EAPI} != 4 ]]; then
+		PYTHON_DEPS+="dev-python/python-exec:=[${PYTHON_USEDEP}]"
+	else
+		PYTHON_DEPS+="dev-python/python-exec:0[${PYTHON_USEDEP}]"
+	fi
 }
 _python_single_set_globals
 
diff --git a/gx86/eclass/python-utils-r1.eclass b/gx86/eclass/python-utils-r1.eclass
index dd1ce0b..bacfc70 100644
--- a/gx86/eclass/python-utils-r1.eclass
+++ b/gx86/eclass/python-utils-r1.eclass
@@ -583,7 +583,11 @@ _python_rewrite_shebang() {
 _python_symlink_wrapper() {
 	debug-print-function ${FUNCNAME} "${@}"
 
-	local from=${ED%/}/usr/bin/python-exec
+	if _python_want_python_exec2; then
+		local from=${ED%/}/usr/lib/python-exec/python-exec2
+	else
+		local from=${ED%/}/usr/bin/python-exec
+	fi
 	local to=${1}
 
 	local frpath=${from%/*}/
@@ -756,20 +760,30 @@ python_newscript() {
 	[[ ${#} -eq 2 ]] || die "Usage: ${FUNCNAME} <path> <new-name>"
 
 	local d=${python_scriptroot:-${DESTTREE}/bin}
+	local wrapd=${d}
 
 	local f=${1}
 	local barefn=${2}
+	local newfn
 
-	local newfn=${barefn}-${EPYTHON}
+	if _python_want_python_exec2; then
+		local PYTHON_SCRIPTDIR
+		python_export PYTHON_SCRIPTDIR
+		d=${PYTHON_SCRIPTDIR#${EPREFIX}}
+		newfn=${barefn}
+	else
+		newfn=${barefn}-${EPYTHON}
+	fi
 
 	(
+		dodir "${wrapd}"
 		exeinto "${d}"
 		newexe "${f}" "${newfn}" || die
 	)
 	_python_rewrite_shebang "${ED%/}/${d}/${newfn}"
 
 	# install the wrapper
-	_python_symlink_wrapper "${ED%/}/${d}/${barefn}"
+	_python_symlink_wrapper "${ED%/}/${wrapd}/${barefn}"
 }
 
 # @ECLASS-VARIABLE: python_moduleroot
@@ -984,5 +998,25 @@ python_is_python3() {
 	[[ ${impl} == python3* ]]
 }
 
+# @FUNCTION: _python_want_python_exec2
+# @INTERNAL
+# @DESCRIPTION:
+# Check whether we should be using python-exec:2.
+_python_want_python_exec2() {
+	debug-print-function ${FUNCNAME} "${@}"
+
+	# EAPI 4 lacks slot operators, so just fix it on python-exec:0.
+	[[ ${EAPI} == 4 ]] && return 1
+
+	# Check if we cached the result, or someone put an override.
+	if [[ ! ${_PYTHON_WANT_PYTHON_EXEC2+1} ]]; then
+		has_version 'dev-python/python-exec:2'
+		_PYTHON_WANT_PYTHON_EXEC2=$(( ! ${?} ))
+	fi
+
+	# Non-zero means 'yes', zero means 'no'.
+	[[ ${_PYTHON_WANT_PYTHON_EXEC2} != 0 ]]
+}
+
 _PYTHON_UTILS_R1=1
 fi
-- 
1.8.3.2